SSC/FreeEnergy/PolytropesEmbedded/Pt3C

Background

Index to original, very long chapter

Free-Energy of Bipolytropes

In this case, the Gibbs-like free energy is given by the sum of four separate energies,

$\mathfrak{𝔊}$

$=$

$[W_{\mathrm{g}\mathrm{r}\mathrm{a}\mathrm{v}}+{\mathfrak{𝔖}}_{\mathrm{t}\mathrm{h}\mathrm{e}\mathrm{r}\mathrm{m}}{]}_{\mathrm{c}\mathrm{o}\mathrm{r}\mathrm{e}}+[W_{\mathrm{g}\mathrm{r}\mathrm{a}\mathrm{v}}+{\mathfrak{𝔖}}_{\mathrm{t}\mathrm{h}\mathrm{e}\mathrm{r}\mathrm{m}}{]}_{\mathrm{e}\mathrm{n}\mathrm{v}}.$

In addition to specifying (generally) separate polytropic indexes for the core, $n_c$, and envelope, $n_e$, and an envelope-to-core mean molecular weight ratio, ${\mu }_e/{\mu }_c$, we will assume that the system is fully defined via specification of the following five physical parameters:

• Total mass, $M_{\mathrm{t}\mathrm{o}\mathrm{t}}$;
• Total radius, $R$;
• Interface radius, $R_i$, and associated dimensionless interface marker, $q\equiv R_i/R$;
• Core mass, $M_c$, and associated dimensionless mass fraction, $\nu \equiv M_c/M_{\mathrm{t}\mathrm{o}\mathrm{t}}$;
• Polytropic constant in the core, $K_c$.

In general, the warped free-energy surface drapes across a five-dimensional parameter "plane" such that,

$\mathfrak{𝔊}$

$=$

$\mathfrak{𝔊}(R,K_c,M_{\mathrm{t}\mathrm{o}\mathrm{t}},q,\nu ).$

Overview

BiPolytrope51

Key Analytic Expressions

Out-of-Equilibrium, Free-Energy Expression for BiPolytropes with $(n_c,n_e)=(5,1)$
${\mathfrak{𝔊}}_{51}^{*}\equiv 2^4\left(\frac{q}{{\nu }^2}\right){\chi }_{\mathrm{e}\mathrm{q}}\left[\frac{{\mathfrak{𝔊}}_{51}}{E_{\mathrm{n}\mathrm{o}\mathrm{r}\mathrm{m}}}\right]$ $=$ $\frac{1}{{\ell }_i^2}[{\mathrm{X}}^{-3/5}(5{\mathfrak{𝔏}}_i)+{\mathrm{X}}^{-3}(4{\mathfrak{𝔎}}_i)-{\mathrm{X}}^{-1}(3{\mathfrak{𝔏}}_i+12{\mathfrak{𝔎}}_i)]$

where,

${\mathfrak{𝔏}}_i$	$\equiv$	$\frac{({\ell }_i^4-1)}{{\ell }_i^2}+\frac{(1+{\ell }_i^2{)}^3}{{\ell }_i^3}\cdot {\tan }^{-1}{\ell }_i,$
${\mathfrak{𝔎}}_i$	$\equiv$	$\frac{{\mathrm{\Lambda }}_i}{{\eta }_i}+\frac{(1+{\mathrm{\Lambda }}_i^2)}{{\eta }_i}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i],$
${\mathrm{\Lambda }}_i$	$\equiv$	$\frac{1}{{\eta }_i}-{\ell }_i,$
${\eta }_i$	$=$	$3\left(\frac{{\mu }_e}{{\mu }_c}\right)\left[\frac{{\ell }_i}{(1+{\ell }_i^2)}\right].$

From the accompanying Table 1 parameter values, we also can write,

$\frac{1}{q}$	$=$	$\frac{{\eta }_s}{{\eta }_i}=1+\frac{1}{{\eta }_i}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i],$
$\nu$	$=$	$\frac{{\ell }_{i}q}{(1+{\mathrm{\Lambda }}_i^2{)}^{1/2}}.$

Consistent with our generic discussion of the stability of bipolytropes and the specific discussion of the stability of bipolytropes having $(n_c,n_e)=(5,1)$, it can straightforwardly be shown that $\partial {\mathfrak{𝔊}}_{51}^{*}/\partial \chi =0$ is satisfied by setting $\mathrm{X}=1$; that is, the equilibrium condition is,

$\chi ={\chi }_{\mathrm{e}\mathrm{q}}$	$=$	$(\frac{\pi }{2^3}{)}^{1/2}\frac{{\nu }^2}{q}\cdot \frac{(1+{\ell }_i^2{)}^3}{3^3{\ell }_i^5}$
	$=$	$\left\{\right(\frac{\pi }{3}\left)2^{2-n_c}{\nu }^{n_c-1}{q}^{3-n_c}\right[\frac{(1+{\ell }_i^2{)}^{6/5}}{(3{\ell }_i^2)}{]}^{n_c}{\}}^{1/(n_c-3)},$

where the last expression has been cast into a form that more clearly highlights overlap with the expression, below, for the equilibrium radius for zero-zero bipolytropes. Furthermore, the equilibrium configuration is unstable whenever,

$[\frac{{\partial }^2{\mathfrak{𝔊}}_{51}^{*}}{\partial {\chi }^2}{]}_{\mathrm{X}=1}<0,$

that is, it is unstable whenever,

$\frac{{\mathfrak{𝔏}}_i}{{\mathfrak{𝔎}}_i}$

$>$

$20.$

Table 1 of an accompanying chapter — and the red-dashed curve in the figure adjacent to that table — identifies some key properties of the model that marks the transition from stable to unstable configurations along equilibrium sequences that have various values of the mean-molecular weight ratio, ${\mu }_e/{\mu }_c$.

Behavior of Equilibrium Sequence

Here we reprint Figure 1 from an accompanying chapter wherein the structure of five-one bipolytropes has been derived. It displays detailed force-balance sequences in the $q-\nu$ plane for a variety of choices of the ratio of mean-molecular-weights, ${\mu }_e/{\mu }_c$, as labeled.

Five-One Bipolytropic Equilibrium Sequences for Various ratios of the mean molecular weight

Limiting Values

Each sequence begins $({\ell }_i=0)$ at the origin, that is, at $(q,\nu )=(0,0)$. As ${\ell }_i\to \mathrm{\infty }$, however, the sequences terminate at different coordinate locations, depending on the value of $m_3\equiv 3({\mu }_e/{\mu }_c)$. In deriving the various limits, it will be useful to note that,

$\frac{1}{{\eta }_i}$	$=$	$\frac{(1+{\ell }_i^2)}{m_3{\ell }_i},$
${\mathrm{\Lambda }}_i$	$=$	$\frac{(1+{\ell }_i^2)}{m_3{\ell }_i}-{\ell }_i$
	$=$	$\frac{1}{m_3{\ell }_i}+\left[\frac{(1-m_3)}{m_3}\right]{\ell }_i$
	$=$	$\frac{1}{m_3{\ell }_i}[1-(m_3-1){\ell }_i^2]$
	$=$	$-\frac{(m_3-1){\ell }_i}{m_3}[1-\frac{1}{(m_3-1){\ell }_i^2}],$
$1+{\mathrm{\Lambda }}_i^2$	$=$	$1+\frac{1}{m_3^2{\ell }_i^2}[1+(1-m_3){\ell }_i^2{]}^2$
	$=$	$\frac{1}{m_3^2{\ell }_i^2}\{m_3^2{\ell }_i^2+[1+(1-m_3){\ell }_i^2{]}^2\}$
	$=$	$\frac{1}{m_3^2{\ell }_i^2}\{1+(2-2m_3+m_3^2){\ell }_i^2+(1-m_3{)}^2{\ell }_i^4\}$

Examining the three relevant parameter regimes, we see that:

• For ${\mu }_e/{\mu }_c<\frac{1}{3}$, that is, $m_3<1$ …

${\tan }^{-1}{\mathrm{\Lambda }}_i{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	${\tan }^{-1}\left[\frac{(1-m_3)}{m_3}\right]{\ell }_i$
	$\approx$	$\frac{\pi }{2}-\left[\frac{m_3}{(1-m_3){\ell }_i}\right]$
$\Rightarrow \frac{1}{q}{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$1+\frac{(1+{\ell }_i^2)}{m_3{\ell }_i}[\pi -\frac{m_3}{(1-m_3){\ell }_i}]$
	$\approx$	$\frac{m_3+\pi {\ell }_i}{m_3}$
$\Rightarrow q{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$\frac{1}{1+(\pi {\ell }_i/m_3)}\to 0.$
	and
$(\frac{\nu }{q}{)}^2$	$=$	$\frac{{\ell }_i^2}{1+{\mathrm{\Lambda }}_i^2}$
	$=$	$m_3^2{\ell }_i^4\{1+(2-2m_3+m_3^2){\ell }_i^2+(1-m_3{)}^2{\ell }_i^4{\}}^{-1}$
	$=$	$m_3^2\{{\ell }_i^{-4}+(2-2m_3+m_3^2){\ell }_i^{-2}+(1-m_3{)}^2{\}}^{-1}$
$\Rightarrow \frac{\nu }{q}{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$\frac{m_3}{1-m_3}$
$\Rightarrow \nu {|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$\left[\frac{m_3}{1-m_3}\right]\frac{1}{1+(\pi {\ell }_i/m_3)}\to 0.$

• For ${\mu }_e/{\mu }_c=\frac{1}{3}$, that is, $m_3=1$ …

${\tan }^{-1}{\mathrm{\Lambda }}_i$	$=$	${\tan }^{-1}\left(\frac{1}{{\ell }_i}\right)$
$\Rightarrow {\tan }^{-1}{\mathrm{\Lambda }}_i{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$\frac{1}{{\ell }_i}$
$\Rightarrow \frac{1}{q}{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$1+\frac{(1+{\ell }_i^2)}{{\ell }_i}[\frac{\pi }{2}+\frac{1}{{\ell }_i}]$
	$\approx$	$\left(\frac{\pi }{2}\right){\ell }_i$
$\Rightarrow q{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$\frac{2}{\pi {\ell }_i}\to 0$
	and
$\left(\frac{\nu }{q}\right)$	$=$	$\frac{{\ell }_i}{(1+1/{\ell }_i^2{)}^{1/2}}$
$\Rightarrow \nu {|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	${\ell }_i\left(\frac{2}{\pi {\ell }_i}\right)=\frac{2}{\pi }\approx 0.63662$

• For ${\mu }_e/{\mu }_c>\frac{1}{3}$, that is, $m_3>1$ …

${\tan }^{-1}{\mathrm{\Lambda }}_i{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	${\tan }^{-1}[-(\frac{m_3-1}{m_3}\left){\ell }_i\right]$
	$\approx$	$-\frac{\pi }{2}+\left[\frac{m_3}{(m_3-1){\ell }_i}\right]$
$\Rightarrow \frac{1}{q}{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$1+\frac{(1+{\ell }_i^2)}{m_3{\ell }_i}\left[\frac{m_3}{(m_3-1){\ell }_i}\right]$
	$=$	$1+\frac{(1+1/{\ell }_i^2)}{(m_3-1)}$
	$\approx$	$1+\frac{1}{(m_3-1)}=\frac{m_3}{(m_3-1)}$
$\Rightarrow q{|}_{{\ell }_i\to \mathrm{\infty }}$	$=$	$\frac{(m_3-1)}{m_3}$
	and
$(\frac{\nu }{q}{)}^2$	$=$	$\frac{{\ell }_i^2}{1+{\mathrm{\Lambda }}_i^2}$
	$=$	$m_3^2{\ell }_i^4\{1+(2-2m_3+m_3^2){\ell }_i^2+(m_3-1{)}^2{\ell }_i^4{\}}^{-1}$
	$=$	$m_3^2\{{\ell }_i^{-4}+(2-2m_3+m_3^2){\ell }_i^{-2}+(m_3-1{)}^2{\}}^{-1}$
$\Rightarrow \frac{\nu }{q}{|}_{{\ell }_i\to \mathrm{\infty }}$	$\approx$	$\frac{m_3}{m_3-1}$
$\Rightarrow \nu {|}_{{\ell }_i\to \mathrm{\infty }}$	$=$	$\frac{m_3}{m_3-1}\left[\frac{m_3-1}{m_3}\right]\to 1.$

Summarizing:

• For ${\mu }_e/{\mu }_c<\frac{1}{3}$, that is, $m_3<1$       …       $(q,\nu {)}_{{\ell }_i\to \mathrm{\infty }}=(0,0).$

• For ${\mu }_e/{\mu }_c=\frac{1}{3}$, that is, $m_3=1$       …       $(q,\nu {)}_{{\ell }_i\to \mathrm{\infty }}=(0,\frac{2}{\pi }).$

• For ${\mu }_e/{\mu }_c>\frac{1}{3}$, that is, $m_3>1$       …       $(q,\nu {)}_{{\ell }_i\to \mathrm{\infty }}=[(m_3-1)/m_3,1].$

Turning Points

Let's identify the location of two turning points along the $\nu (q)$ sequence — one defines $q_{\mathrm{m}\mathrm{a}\mathrm{x}}$ and the other identifies ${\nu }_{\mathrm{m}\mathrm{a}\mathrm{x}}$. They occur, respectively, where,

$\frac{d\ln q}{d\ln {\ell }_i}=0$

and

$\frac{d\ln \nu }{d\ln {\ell }_i}=0.$

In deriving these expressions, we will use the relations,

$\frac{d{\eta }_i}{d{\ell }_i}$	$=$	$\frac{m_3(1-{\ell }_i^2)}{(1+{\ell }_i^2{)}^2},$
$\frac{d{\mathrm{\Lambda }}_i}{d{\ell }_i}$	$=$	$-\frac{1}{m_3{\ell }_i^2}[1-{\ell }_i^2(1-m_3)],$

where,

$m_3\equiv 3\left(\frac{{\mu }_e}{{\mu }_c}\right).$

Given that,

$q$

$=$

$\{1+\frac{1}{{\eta }_i}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]{\}}^{-1},$

we find,

$\frac{d\ln q}{d\ln {\ell }_i}$	$=$	$\frac{{\ell }_i}{q}\cdot (-q^2)\frac{d}{d{\ell }_i}\left\{\frac{1}{{\eta }_i}\right[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i\left]\right\}$
	$=$	$-q{\ell }_i\{-\frac{1}{{\eta }_i^2}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]\frac{d{\eta }_i}{d{\ell }_i}+\frac{1}{{\eta }_i(1+{\mathrm{\Lambda }}_i^2)}\frac{d{\mathrm{\Lambda }}_i}{d{\ell }_i}\}$
	$=$	$q{\ell }_i\left\{\frac{(1-{\ell }_i^2)}{m_3{\ell }_i^2}\right[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]+\frac{(1+{\ell }_i^2)}{m_3^2{\ell }_i^3(1+{\mathrm{\Lambda }}_i^2)}[1-{\ell }_i^2(1-m_3)\left]\right\}$
	$=$	$\frac{q}{m_3^2}{\ell }_i^2\{m_3{\ell }_i(1-{\ell }_i^2)[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]+\frac{(1+{\ell }_i^2)}{(1+{\mathrm{\Lambda }}_i^2)}[1-{\ell }_i^2(1-m_3)\left]\right\}.$

And, given that,

$\nu$

$=$

$\frac{{\ell }_{i}q}{(1+{\mathrm{\Lambda }}_i^2{)}^{1/2}}.$

we find,

$\frac{d\ln \nu }{d\ln {\ell }_i}$	$=$	$\frac{{\ell }_i}{\nu }\{\frac{q}{(1+{\mathrm{\Lambda }}_i^2{)}^{1/2}}+\frac{q}{(1+{\mathrm{\Lambda }}_i^2{)}^{1/2}}\frac{d\ln q}{d\ln {\ell }_i}-\frac{{\ell }_{i}q{\mathrm{\Lambda }}_i}{(1+{\mathrm{\Lambda }}_i^2{)}^{3/2}}\frac{d{\mathrm{\Lambda }}_i}{d{\ell }_i}\}$
	$=$	$\frac{q{\ell }_i}{\nu (1+{\mathrm{\Lambda }}_i^2{)}^{1/2}}\{1+\frac{d\ln q}{d\ln {\ell }_i}+\frac{{\mathrm{\Lambda }}_i}{m_3{\ell }_i(1+{\mathrm{\Lambda }}_i^2)}[1-{\ell }_i^2(1-m_3)\left]\right\}$

In summary, then, the $q_{\mathrm{m}\mathrm{a}\mathrm{x}}$ turning point occurs where,

$0$

$=$

$(1+{\mathrm{\Lambda }}_i^2)[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]+\frac{(1+{\ell }_i^2)}{m_3{\ell }_i(1-{\ell }_i^2)}[1-{\ell }_i^2(1-m_3)];$

and the ${\nu }_{\mathrm{m}\mathrm{a}\mathrm{x}}$ turning point occurs where,

$0$	$=$	$1+\frac{{\mathrm{\Lambda }}_i}{m_3{\ell }_i(1+{\mathrm{\Lambda }}_i^2)}[1-{\ell }_i^2(1-m_3)]+\frac{q{\ell }_i^3(1-{\ell }_i^2)}{m_3}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]+\frac{q{\ell }_i^2}{m_3^2}\cdot \frac{(1+{\ell }_i^2)}{(1+{\mathrm{\Lambda }}_i^2)}[1-{\ell }_i^2(1-m_3)]$
	$=$	$1+\frac{q{\ell }_i^3(1-{\ell }_i^2)}{m_3}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]+[\frac{{\mathrm{\Lambda }}_i}{m_3{\ell }_i(1+{\mathrm{\Lambda }}_i^2)}+\frac{q{\ell }_i^2}{m_3^2}\cdot \frac{(1+{\ell }_i^2)}{(1+{\mathrm{\Lambda }}_i^2)}]\cdot [1-{\ell }_i^2(1-m_3)]$
	$=$	$1+\frac{q{\ell }_i^3(1-{\ell }_i^2)}{m_3}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]+\frac{1}{m_3{\ell }_i}[\frac{{\mathrm{\Lambda }}_i}{(1+{\mathrm{\Lambda }}_i^2)}+\frac{q{\ell }_i^3}{m_3}\cdot \frac{(1+{\ell }_i^2)}{(1+{\mathrm{\Lambda }}_i^2)}]\cdot [1-{\ell }_i^2(1-m_3)].$

NOTE:  As we show above, for the special case of $m_3=1$ — that is, when ${\mu }_e/{\mu }_c=\frac{1}{3}$, precisely — the equilibrium sequence (as ${\ell }_i\to \mathrm{\infty }$) intersects the $q=0$ axis at precisely the value, $\nu =2/\pi$. As is illustrated graphically in Figure 1 of an accompanying chapter, no ${\nu }_{\mathrm{m}\mathrm{a}\mathrm{x}}$ turning point exists for values of $m_3>1$.

For the record, we repeat, as well, that the transition from stable to dynamically unstable configurations occurs along the sequence when,

$\frac{({\ell }_i^4-1)}{{\ell }_i^2}+\frac{(1+{\ell }_i^2{)}^3}{{\ell }_i^3}\cdot {\tan }^{-1}{\ell }_i$	$=$	$20\{\frac{{\mathrm{\Lambda }}_i}{{\eta }_i}+\frac{(1+{\mathrm{\Lambda }}_i^2)}{{\eta }_i}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i\left]\right\}$
	$=$	$\frac{20(1+{\mathrm{\Lambda }}_i^2)(1+{\ell }_i^2)}{m_3{\ell }_i}\{\frac{{\mathrm{\Lambda }}_i}{(1+{\mathrm{\Lambda }}_i^2)}+[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i\left]\right\}$
$\Rightarrow m_3{\ell }_i({\ell }_i^4-1)+m_3(1+{\ell }_i^2{)}^3\cdot {\tan }^{-1}{\ell }_i$	$=$	$20{\ell }_i^2(1+{\mathrm{\Lambda }}_i^2)(1+{\ell }_i^2)\{\frac{{\mathrm{\Lambda }}_i}{(1+{\mathrm{\Lambda }}_i^2)}+[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i\left]\right\}$
$\Rightarrow \frac{m_3{\ell }_i({\ell }_i^4-1)+m_3(1+{\ell }_i^2{)}^3\cdot {\tan }^{-1}{\ell }_i}{20{\ell }_i^2(1+{\ell }_i^2)}$	$=$	${\mathrm{\Lambda }}_i+(1+{\mathrm{\Lambda }}_i^2)[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i].$

In order to clarify what equilibrium sequences do not have any turning points, let's examine how the $q_{\mathrm{m}\mathrm{a}\mathrm{x}}$ turning-point expression behaves as ${\ell }_i\to \mathrm{\infty }$.

$\frac{(1+{\ell }_i^2)}{(1+{\mathrm{\Lambda }}_i^2)}[1-{\ell }_i^2(1-m_3)]$	$=$	$m_3{\ell }_i({\ell }_i^2-1)[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]$
$\Rightarrow \frac{(1+{\ell }_i^2)}{m_3{\ell }_i({\ell }_i^2-1)}[1+{\ell }_i^2(m_3-1)]$	$=$	$\{1+\frac{1}{m_3^2{\ell }_i^2}[(m_3-1){\ell }_i^2-1{]}^2\left\}\right\{\frac{\pi }{2}+[-\frac{\pi }{2}-\frac{1}{{\mathrm{\Lambda }}_i}+\frac{1}{3{\mathrm{\Lambda }}_i^3}+{𝒪}({\mathrm{\Lambda }}_i^{-5})]\}$
$\Rightarrow \frac{(1+{\ell }_i^2){\ell }_i^2(m_3-1)}{m_3{\ell }_i({\ell }_i^2-1)}[1+\frac{1}{{\ell }_i^2(m_3-1)}]$	$=$	$\{1+\frac{(m_3-1{)}^2{\ell }_i^2}{m_3^2}[1-\frac{1}{(m_3-1){\ell }_i^2}{]}^2\}\cdot \frac{1}{(-{\mathrm{\Lambda }}_i)}[1-\frac{1}{3{\mathrm{\Lambda }}_i^2}+{\xcancel{{𝒪}({\mathrm{\Lambda }}_i^{-4})}}^0]$
$\Rightarrow \frac{(1+{\ell }_i^2)}{{\ell }_i({\ell }_i^2-1)}\cdot \frac{m_3}{(m_3-1)}[1+\frac{1}{{\ell }_i^2(m_3-1)}]$	$=$	$[1-\frac{2}{(m_3-1){\ell }_i^2}+\frac{m_3^2}{(m_3-1{)}^2{\ell }_i^2}+\frac{1}{(m_3-1{)}^2{\ell }_i^4}]\cdot \frac{m_3}{(m_3-1){\ell }_i}[1-\frac{1}{(m_3-1){\ell }_i^2}{]}^{-1}\{1-\frac{m_3^2}{3(m_3-1{)}^2{\ell }_i^2}[1-\frac{1}{(m_3-1){\ell }_i^2}{]}^{-2}\}$
$\Rightarrow (1+\frac{1}{{\ell }_i^2})[1+\frac{1}{{\ell }_i^2(m_3-1)}][1-\frac{1}{(m_3-1){\ell }_i^2}]$	$=$	$(1-\frac{1}{{\ell }_i^2})[1-\frac{2}{(m_3-1){\ell }_i^2}+\frac{m_3^2}{(m_3-1{)}^2{\ell }_i^2}+\frac{1}{(m_3-1{)}^2{\ell }_i^4}]\{1-\frac{m_3^2}{3(m_3-1{)}^2{\ell }_i^2}[1-\frac{1}{(m_3-1){\ell }_i^2}{]}^{-2}\}$

The leading-order term is unity on both sides of this expression, so they cancel; let's see what results from keeping terms $\propto {\ell }_i^{-2}$.

$\frac{1}{{\ell }_i^2}[1+\frac{1}{(m_3-1)}-\frac{1}{(m_3-1)}]$	$=$	$\frac{1}{{\ell }_i^2}[-1-\frac{2}{(m_3-1)}+\frac{m_3^2}{(m_3-1{)}^2}-\frac{m_3^2}{3(m_3-1{)}^2}]$
$\Rightarrow 2$	$=$	$-\frac{2}{(m_3-1)}+\frac{2m_3^2}{3(m_3-1{)}^2}$
$\Rightarrow 6(m_3-1{)}^2$	$=$	$-6(m_3-1)+2m_3^2$
$\Rightarrow 6m_3^2-12m_3+6$	$=$	$-6m_3+6+2m_3^2$
$\Rightarrow m_3$	$=$	$\frac{3}{2}.$

We therefore conclude that the $q_{\mathrm{m}\mathrm{a}\mathrm{x}}$ turning point does not appear along any sequence for which,

$m_3$	$>$	$\frac{3}{2}$
$\Rightarrow \frac{{\mu }_e}{{\mu }_c}$	$>$	$\frac{1}{2}.$

Five-One Bipolytrope Equilibrium Sequences in $q-\nu$ Plane
Full Sequences for Various $\frac{{\mu }_e}{{\mu }_c}$	Magnified View with Turning Points and Stability Transition-Points Identified

Graphical Depiction of Free-Energy Surface

Figure 1:   Free-Energy Surface for $(n_c,n_e)=(5,1)$ and $\frac{{\mu }_e}{{\mu }_c}=1$

Free-Energy surface for 5_1 bipolytrope Free-Energy surface for 5_1 bipolytrope Left Panel: The free energy (vertical, blue axis) is plotted as a function of the radial interface location, ${\xi }_i$ (red axis), and the normalized configuration radius, $\mathrm{X}\equiv \chi /{\chi }_{\mathrm{e}\mathrm{q}}$ (green axis). Right Panel: Same as the left panel, but animated in order to highlight undulations of the surface. The value of the free energy is indicated by color as well as by the height of the warped surface — red identifies the lowest depicted energies while blue identifies the highest depicted energies; these same colors have been projected down onto the $z=0$ plane to present a two-dimensional, color-contour plot. A multi-colored line segment drawn parallel to the ${\xi }_i$ axis at the value, $\mathrm{X}=1$, identifies the configuration's equilibrium radius for each value of the interface location. Equilibrium configurations marked in white lie at the bottom of the principal free-energy "valley" and are stable, while configurations marked in blue lie at the top of a free-energy "hill," indicating that they are unstable; the red dot identifies the location along this equilibrium sequence where the transition from stable to unstable configurations occurs.

For purposes of reproducibility, it is incumbent upon us to clarify how the values of the free energy were normalized in order to produce the free-energy surface displayed in Figure 1. The normalization steps are explicitly detailed within the fortran program, below, that generated the data for plotting purposes; here we provide a brief summary. We evaluated the normalized free energy, ${\mathfrak{𝔊}}_{51}^{*}$, across a $200\times 200$ zone grid of uniform spacing, covering the following $(x,y)=({\ell }_i,\mathrm{X})$ domain:

$\frac{1}{\sqrt{3}}$	$\le {\ell }_i\le$	$\frac{3}{\sqrt{3}}$
$0.469230769$	$\le \mathrm{X}\le$	$2.0$

(With this specific definition of the y-coordinate grid, $\mathrm{X}=1$ is associated with zone 70.) After this evaluation, a constant, $E_{\mathrm{f}\mathrm{u}\mathrm{d}\mathrm{g}\mathrm{e}}=-10$, was added to ${\mathfrak{𝔊}}^{*}$ in order to ensure that the free energy was negative across the entire domain. Then (inorm = 1), for each specified interface location, $x={\ell }_i$, employing the equilibrium value of the free energy,

$E_0={\mathfrak{𝔊}}_{51}^{*}({\ell }_i,\mathrm{X}=1)+E_{\mathrm{f}\mathrm{u}\mathrm{d}\mathrm{g}\mathrm{e}},$

the free energy was normalized across all values of $y=\mathrm{X}$ via the expression,

$\mathrm{f}\mathrm{e}=\frac{({\mathfrak{𝔊}}_{51}^{*}+E_{\mathrm{f}\mathrm{u}\mathrm{d}\mathrm{g}\mathrm{e}})-(E_0{)}_i}{|E_0{|}_i}.$

Finally, for plotting purposes, at each grid cell vertex ("vertex") — as well as at each grid cell center ("cell") — the value of the free energy, $\mathrm{f}\mathrm{e}$, was renormalized as follows,

$\mathrm{v}\mathrm{e}\mathrm{r}\mathrm{t}\mathrm{e}\mathrm{x}=\frac{\mathrm{f}\mathrm{e}-\mathrm{m}\mathrm{i}\mathrm{n}(\mathrm{f}\mathrm{e})}{\mathrm{m}\mathrm{a}\mathrm{x}(\mathrm{f}\mathrm{e})-\mathrm{m}\mathrm{i}\mathrm{n}(\mathrm{f}\mathrm{e})}.$

Via this last step, the minimum "vertex" energy across the entire domain was 0.0 while the maximum "vertex" energy was 1.0.

FORTRAN Program Documentation			Example Evaluations (See also associated Table 1)
Coord. Axis	Coord. Name	Associated Physical Quantity	$\frac{{\mu }_e}{{\mu }_c}=1$	$\frac{{\mu }_e}{{\mu }_c}=0.305$
x-axis	bsize	${\ell }_i\equiv \frac{{\xi }_i}{\sqrt{3}}$	$\frac{2.416}{\sqrt{3}}=1.395$	$\frac{8.1938}{\sqrt{3}}=4.7307$	$\frac{14.389}{\sqrt{3}}=8.3076$
y-axis	csize	$\mathrm{X}\equiv \frac{\chi }{{\chi }_{\mathrm{e}\mathrm{q}}}$	$1$	$1$	$1$
Relevant Lines of Code
eta = 3.0d0*muratio*bsize/(1.0d0+bsize**2) Gami = 1.0d0/eta-bsize frakL = (bsize**4-1.0d0)/bsize**2 + & & DATAN(bsize)*((1.0d0+bsize**2)/bsize)**3 frakK = Gami/eta + ((1.0d0+Gami**2)/eta)*(pii/2.0d0+DATAN(Gami)) E0 = ((5.0d0*frakL) + (4.0d0*frakK)& & - (3.0d0*frakL+12.0d0*frakK))/bsize**2+Efudge fescalar(j,k) = (csize**(-0.6d0)*(5.0d0*frakL)& & + csize**(-3.0d0)*(4.0d0*frakK)& & - (3.0d0*frakL+12.0d0*frakK)/csize)/bsize**2 + Efudge if(inorm.eq.1)fescalar(j,k)=fescalar(j,k)/DABS(E0) & & - E0/DABS(E0)
Variable	Represents	Value calculated via the expression …
eta	${\eta }_i$	$3\left(\frac{{\mu }_e}{{\mu }_c}\right)\left[\frac{{\ell }_i}{(1+{\ell }_i^2)}\right]$	$1.421$	$0.1851$	$0.1086$
Gami	${\mathrm{\Lambda }}_i$	$\frac{1}{{\eta }_i}-{\ell }_i$	$-0.691$	$0.6705$	$0.9033$
frakL	${\mathfrak{𝔏}}_i$	$\frac{({\ell }_i^4-1)}{{\ell }_i^2}+[\frac{1+{\ell }_i^2}{{\ell }_i}{]}^3{\tan }^{-1}{\ell }_i$	$10.37$	$186.80$	$937.64$
frakK	${\mathfrak{𝔎}}_i$	$\frac{{\mathrm{\Lambda }}_i}{{\eta }_i}+\frac{(1+{\mathrm{\Lambda }}_i^2)}{{\eta }_i}[\frac{\pi }{2}+{\tan }^{-1}{\mathrm{\Lambda }}_i]$	$0.518$	$20.544$	$46.882$
	$\frac{{\mathfrak{𝔏}}_i}{{\mathfrak{𝔎}}_i}$		$20$	$9.093$	$20$
E0 - Efudge	${\mathfrak{𝔊}}_{51}^{*}({\ell }_i,\mathrm{X}=1)$	$\frac{1}{{\ell }_i^2}[5{\mathfrak{𝔏}}_i+4{\mathfrak{𝔎}}_i-(3{\mathfrak{𝔏}}_i+12{\mathfrak{𝔎}}_i)]=\frac{2({\mathfrak{𝔏}}_i-4{\mathfrak{𝔎}}_i)}{{\ell }_i^2}$	$8.525$	$9.3496$	$21.737$

Figure 2:   Free-Energy Surface for $(n_c,n_e)=(5,1)$ and $\frac{{\mu }_e}{{\mu }_c}=0.305$

Free-Energy surface for 5_1 bipolytrope Left Panel: The free energy (vertical, blue axis) is plotted as a function of the radial interface location, ${\xi }_i$ (red axis), and the normalized configuration radius, $\mathrm{X}\equiv \chi /{\chi }_{\mathrm{e}\mathrm{q}}$ (green axis). Right Panel: Same as the left panel, but animated in order to highlight undulations of the surface. The value of the free energy is indicated by color as well as by the height of the warped surface — red identifies the lowest depicted energies while blue identifies the highest depicted energies; these same colors have been projected down onto the $z=0$ plane to present a two-dimensional, color-contour plot. A multi-colored line segment drawn parallel to the ${\xi }_i$ axis at the value, $\mathrm{X}=1$, identifies the configuration's equilibrium radius for each value of the interface location. Equilibrium configurations marked in white lie at the bottom of the principal free-energy "valley" and are stable, while configurations marked in blue lie at the top of a free-energy "hill," indicating that they are unstable; the red dot identifies the location along this equilibrium sequence where the transition from stable to unstable configurations occurs.

BiPolytrope00

Out-of-Equilibrium, Free-Energy Expression for BiPolytropes with Structural $(n_c,n_e)=(0,0)$
${\mathfrak{𝔊}}_{00}^{*}\equiv 5\left(\frac{q}{{\nu }^2}\right){\chi }_{\mathrm{e}\mathrm{q}}\left[\frac{{\mathfrak{𝔊}}_{00}}{E_{\mathrm{n}\mathrm{o}\mathrm{r}\mathrm{m}}}\right]$ $=$ $\frac{5}{2q^3}[n_c{A}_2{\mathrm{X}}^{-3/n_c}+n_e{B}_2{\mathrm{X}}^{-3/n_e}-3C_2{\mathrm{X}}^{-1}]$

where,

$A_2$	$\equiv$	$\frac{2}{5}{q}^3[1+q^3(f-1-\mathfrak{𝔉})],$
$B_2$	$\equiv$	$\frac{2}{5}{q}^{3}f-A_2,$
$C_2$	$\equiv$	$\frac{2}{5}{q}^{3}f,$
$f$	$\equiv$	$1+\frac{5}{2}\left(\frac{{\rho }_e}{{\rho }_c}\right)(\frac{1}{q^2}-1)+\left(\frac{{\rho }_e}{{\rho }_c}{)}^2\right[\frac{1}{q^5}-1+\frac{5}{2}(1-\frac{1}{q^2})],$
$\mathfrak{𝔉}$	$\equiv$	$\frac{5}{2}\left(\frac{{\rho }_e}{{\rho }_c}\right)\frac{1}{q^5}[(-2q^2+3q^3-q^5)+\frac{3}{5}(\frac{{\rho }_e}{{\rho }_c})(-1+5q^2-5q^3+q^5)],$
$\frac{{\rho }_e}{{\rho }_c}$	$=$	$\frac{q^3(1-\nu )}{\nu (1-q^3)}.$

The associated equilibrium radius is,

${\chi }_{\mathrm{e}\mathrm{q}}$

$=$

$\left\{\right(\frac{\pi }{3}\left)2^{2-n_c}{\nu }^{n_c-1}{q}^{3-n_c}\right[1+\frac{2}{5}{q}^3(f-1-\mathfrak{𝔉}){]}^{n_c}{\}}^{1/(n_c-3)}.$

We have deduced that the system is unstable if,

$\frac{n_e}{3}\left[\frac{3-n_e}{n_c-n_e}\right]$

$<$

$\frac{A_2}{C_2}=\frac{1}{f}[1+q^3(f-1-\mathfrak{𝔉})].$

Fortran Code

This is the program that generated the free-energy data for the "five-one" bipolytrope that is displayed in the above, Figure 1 image/animation.

      PROGRAM BiPolytrope
      real*8 pii
      real*8 bmin,bmax,cmin,cmax,db,dc
      real*8 c(200),b(200),chalf(199),bhalf(199)
      real*8 bsize,csize,emin,emax
      real*8 fepoint(200,200),fescalar(199,199)
      real*8 ell(200),ellhalf(199)
      real*8 muratio,eta,Gami,frakK,frakL
      real*8 eshift,ediff
      real   xx(200),yy(200),cell(199,199),vertex(200,200)
      real   valuemin,minlog,valufudge
      real*8 q,nu,chiEq,Enorm,E0,Efudge
      integer j,k,n,nmax,inorm
  101 format(4x,'bsize',7x,'csize',8x,'xi',10x,'A',12x,'B',12x,&
     &'fM',13x,'fW',11x,'fA',/)
! 102 format(1p8d12.4)
  103 format(2i5,1p3d14.6)
  201 format(5x,'valuemin = ',1pe15.5,//)
  205 format(5x,'For Cell-center ... emin, emax = ',1p2d14.6,/)
  206 format(5x,'For Cell-vertex ... emin, emax = ',1p2d14.6,/)
  701 format(5x,1p10d10.2)  
  700 format(8x,'xi',9x,'ell',8x,'eta',8x,'Lambda',5x,'frakK',&
     &       5x,'frakL',8x,'q',5x,'nu',5x,'chiEq',8x,'E0',/)
!!!!!!!!
!!!!!!!!
      inorm=1
      pii = 4.0d0*datan(1.0d0) 
      muratio = 1.0d0
      bsize = 0.0d0
      csize = 0.0d0
      Efudge = -10.0d0
      write(*,101)
!     write(*,102)bsize,csize,xival,coefA,coefB,fM,fW,fA
!!!!!!!!!!!
!
!  In this free-energy routine, c = X = chi/chi_eq and b = xi_i
!
!!!!!!!!!!!
      nmax = 200
      bmin = 1.0d0
      bmax = 3.0d0
      db   = (bmax-bmin)/dfloat(nmax-1)
      b(1) = bmin
      ell(1) = b(1)/dsqrt(3.0d0)
!  These values of cmin and cmax ensure that X=1 occurs at zone 70
      cmin = 0.469230769d0
      cmax = 2.00d0
      dc   = (cmax-cmin)/dfloat(nmax-1)
      c(1) = cmin
      do n=2,nmax
        b(n) = b(n-1)+db
        c(n) = c(n-1)+dc
        ell(n) = b(n)/dsqrt(3.0d0)
      enddo
      do n=1,nmax-1
        bhalf(n) = 0.5d0*(b(n)+b(n+1))
        chalf(n) = 0.5d0*(c(n)+c(n+1))
        ellhalf(n) = bhalf(n)/dsqrt(3.0d0)
      enddo
!
!  BEGIN LOOP to evaluate free energy (cell center)
!
      emin = 0.0d0
      emax = 0.0d0
      write(*,700)
      do j=1,nmax-1
        bsize = ellhalf(j)
      eta = 3.0d0*muratio*bsize/(1.0d0+bsize**2)
      Gami = 1.0d0/eta-bsize
      frakL = (bsize**4-1.0d0)/bsize**2 + &
     &        DATAN(bsize)*((1.0d0+bsize**2)/bsize)**3
      frakK = Gami/eta + ((1.0d0+Gami**2)/eta)*(pii/2.0d0+DATAN(Gami))
      q = 1.0d0/(1.0d0 + (0.5d0*pii+DATAN(Gami))/eta)
      nu = bsize*q/dsqrt(1.0d0+Gami**2)
      chiEq = dsqrt(pii/8.0d0)*(nu**2/(q*bsize**2))&
     &        *((1.0d0+bsize**2)/(3.0d0*bsize))**3
      Enorm = 16.0d0*(q/nu**2)*chiEq
      E0    = ((5.0d0*frakL) + (4.0d0*frakK)&
     &        - (3.0d0*frakL+12.0d0*frakK))/bsize**2+Efudge
      write(*,701)b(j),bsize,eta,Gami,frakK,frakL,q,nu,chiEq,E0
        do k=1,nmax-1
          csize=chalf(k)
          fescalar(j,k) = (csize**(-0.6d0)*(5.0d0*frakL)&
     &        + csize**(-3.0d0)*(4.0d0*frakK)&
     &   - (3.0d0*frakL+12.0d0*frakK)/csize)/bsize**2 + Efudge
          if(inorm.eq.1)fescalar(j,k)=fescalar(j,k)/DABS(E0) &
     &                  - E0/DABS(E0)
        if(fescalar(j,k).gt.0.5d0)fescalar(j,k)=0.5d0
          if(fescalar(j,k).lt.emin)emin=fescalar(j,k)
          if(fescalar(j,k).gt.emax)emax=fescalar(j,k)
!         write(*,103)j,k,bsize,csize,fescalar(j,k)
        enddo
      enddo
      write(*,205)emin,emax
!
!  BEGIN LOOP to evaluate free energy (cell vertex)
!
      emin = 0.0d0
      emax = 0.0d0
      do j=1,nmax
        bsize = ell(j)
      eta = 3.0d0*muratio*bsize/(1.0d0+bsize**2)
      Gami = 1.0d0/eta-bsize
      frakL = (bsize**4-1.0d0)/bsize**2 + &
     &        DATAN(bsize)*((1.0d0+bsize**2)/bsize)**3
      frakK = Gami/eta + ((1.0d0+Gami**2)/eta)*(pii/2.0d0+DATAN(Gami))
      q = 1.0d0/(1.0d0 + (0.5d0*pii+DATAN(Gami))/eta)
      nu = bsize*q/dsqrt(1.0d0+Gami**2)
      chiEq = dsqrt(pii/8.0d0)*(nu**2/(q*bsize**2))&
     &        *((1.0d0+bsize**2)/(3.0d0*bsize))**3
      Enorm = 16.0d0*(q/nu**2)*chiEq
      E0    = ((5.0d0*frakL) + (4.0d0*frakK)&
     &        - (3.0d0*frakL+12.0d0*frakK))/bsize**2 + Efudge
        do k=1,nmax
          csize=c(k)
          fepoint(j,k) = (csize**(-0.6d0)*(5.0d0*frakL)&
     &        + csize**(-3.0d0)*(4.0d0*frakK)&
     &   - (3.0d0*frakL+12.0d0*frakK)/csize)/bsize**2 + Efudge
          if(inorm.eq.1)fepoint(j,k)=fepoint(j,k)/DABS(E0) &
     &                  - E0/DABS(E0)
        if(fepoint(j,k).gt.0.5d0)fepoint(j,k)=0.5d0
          if(fepoint(j,k).lt.emin)emin=fepoint(j,k)
          if(fepoint(j,k).gt.emax)emax=fepoint(j,k)
!         write(*,103)j,k,bsize,csize,fepoint(j,k)
        enddo
      enddo
      write(*,206)emin,emax
!
!  Now fill single-precision arrays for plotting.
!
      do n=1,nmax
!       xx(n)=b(n)/b(nmax)
!       yy(n)=c(n)/c(nmax)
        xx(n)=b(n)-bmin
        yy(n)=c(n)-cmin
!       xx(n)=b(n)
!       yy(n)=c(n)
      enddo
      valuemin= -emin
      valufudge = 1.0d0/(emax-emin)
      do k=1,nmax
        do j=1,nmax
          vertex(j,k)=fepoint(j,k)+valuemin
          vertex(j,k)=vertex(j,k)*valufudge
        enddo
      enddo
      do k=1,nmax-1
        do j=1,nmax-1
          cell(j,k)=fescalar(j,k)+valuemin
          cell(j,k)=cell(j,k)*valufudge
        enddo
      enddo
      call XMLwriter01(nmax,xx,yy,cell,vertex)
      stop
      END PROGRAM BiPolytrope
      Subroutine XMLwriter01(imax,x,y,cell_scalar,point_scalar)
      real x(200),y(200),z(1)
      real cell_scalar(199,199),point_scalar(200,200)
      integer imax
      integer extentX,extentY,extentZ
      integer ix0,iy0,iz0
      integer norm(200,3)
!     imax=200
      ix0=0
      iy0=0
      iz0=0
      extentX=imax-1
      extentY=imax-1
      extentZ=0
      z(1) = 0.0
! Set normal vector 1D array
      do i=1,imax
        norm(i,1)=0
        norm(i,2)=0
        norm(i,3)=1
      enddo
  201 format('<?xml version="1.0"?>')
  202 format('<VTKFile type="RectilinearGrid" version="0.1" byte_order="LittleEndian">')
  302 format('</VTKFile>')
  203 format(2x,'<RectilinearGrid WholeExtent="',6I4,'">')
  303 format(2x,'</RectilinearGrid>')
  204 format(4x,'<Piece Extent="',6I4,'">')
  304 format(4x,'</Piece>')
  205 format(6x,'<CellData Scalars="cell_scalars" Normals="magnify">')
  305 format(6x,'</CellData>')
  206 format(8x,'<DataArray type="Float32" Name="magnify" NumberOfComponents="3" format="ascii">')
  207 format(8x,'<DataArray type="Float32" Name="cell_scalars" format="ascii">')
  399 format(8x,'</DataArray>')
  208 format(6x,'<PointData Scalars="colorful" Normals="direction">')
  308 format(6x,'</PointData>')
  209 format(8x,'<DataArray type="Float32" Name="colorful" format="ascii">')
  210 format(6x,'<Coordinates>')
  310 format(6x,'</Coordinates>')
  211 format(8x,'<DataArray type="Float32" format="ascii" RangeMin="0" RangeMax="5">')
  212 format(8x,'<DataArray type="Float32" format="ascii">')
  213 format(8x,'<DataArray type="Float32" Name="direction" NumberOfComponents="3" format="ascii">')
  501 format(10f9.5)
  502 format(10f9.5)
  503 format(5x,9(1x,3I2))
  504 format(10f9.5)
  505 format(5x,10(1x,3I2))
!!!!!
!
!  Begin writing out XML tags.
!
!!!!!
      write(*,201)                              !<?xml
      write(*,202)                              !VTKFile
        write(*,203)ix0,extentX,iy0,extentY,iz0,extentZ        !  RectilinearGrid
          write(*,204)ix0,extentX,iy0,extentY,iz0,extentZ      !    Piece
            write(*,205)                        !      CellData
              write(*,207)                      !        DataArray(cell_scalars)
      do j=1,imax-1
      write(*,501)(cell_scalar(i,j),i=1,imax-1)
      enddo
              write(*,399)                      !        /DataArray
              write(*,206)                      !        DataArray(cell_scalars)
      do j=1,imax-1
      write(*,503)(norm(i,1),norm(i,2),norm(i,3),i=1,imax-1)
      enddo
              write(*,399)                      !        /DataArray
            write(*,305)                        !      /CellData
            write(*,208)                        !      PointData
              write(*,209)                      !        DataArray(points)
      write(*,502)((point_scalar(i,j),i=1,imax),j=1,imax)
              write(*,399)                      !        /DataArray
              write(*,213)                      !        DataArray(cell_scalars)
      do j=1,imax
      write(*,505)(norm(i,1),norm(i,2),norm(i,3),i=1,imax)
      enddo
              write(*,399)                      !        /DataArray
            write(*,308)                        !      /PointData
            write(*,210)                        !      Coordinates
              write(*,212)                      !        DataArray(x-direction)
        write(*,504)(x(i),i=1,imax)
              write(*,399)                      !        /DataArray
              write(*,212)                      !        DataArray(y-direction)
        write(*,504)(y(i),i=1,imax)
              write(*,399)                      !        /DataArray
              write(*,212)                      !        DataArray(z-direction)
        write(*,504)z(1)
              write(*,399)                      !        /DataArray
            write(*,310)                        !      /Coordinates
          write(*,304)                          !    /Piece
        write(*,303)                            !  /RectilinearGrid
      write(*,302)                              !/VTKFile
      return
      end

Nonstandard Examination

In our introductory remarks, above, we said the warped free-energy surface drapes across a five-dimensional parameter "plane" such that,

${\mathfrak{𝔊}}_{51}$

$=$

$\mathfrak{𝔊}(R,K_c,M_{\mathrm{t}\mathrm{o}\mathrm{t}},q,\nu ).$

From a more pragmatic point of view, we should have said that the "five-one" free-energy surface drapes across a five-dimensional parameter "plane" such that,

${\mathfrak{𝔊}}_{51}$

$=$

$\mathfrak{𝔊}(R,K_c,M_{\mathrm{t}\mathrm{o}\mathrm{t}},{\ell }_i,\frac{{\mu }_e}{{\mu }_c}).$

In our initial, standard examination of the structure of this warped free-energy surface, we held three parameters fixed — namely, $K_c,M_{\mathrm{t}\mathrm{o}\mathrm{t}},\frac{{\mu }_e}{{\mu }_c}$ — and plotted ${\mathfrak{𝔊}}_{51}({\ell }_i,\mathrm{X}\equiv R/R_{\mathrm{e}\mathrm{q}})$. Now, let's fix $\mathrm{X}=1$ and plot ${\mathfrak{𝔊}}_{51}({\ell }_i,\frac{{\mu }_e}{{\mu }_c})$. The following plot shows how a portion of the $({\ell }_i,{\mu }_e/{\mu }_c)$ grid maps onto the traditional $(q,\nu )$ plane. The numerical labels identify lines of constant ${\xi }_i=\sqrt{3}{\ell }_i$ — 7 (light green), 9 (pink), and 12 (orange) — and lines of constant ${\mu }_e/{\mu }_c$ — 0.330 (purple), 0.315 (dark green), and 0.305 (white/blue).

xi-ell grid drawn on q-nu grid

See Also

In October 2023, this very long chapter was subdivided in order to more effectively accommodate edits. Here is a list of the resulting set of shorter chapters:

1. Free-Energy Synopsis
2. Free-Energy of Truncated Polytropes
3. Free-Energy of BiPolytropes
   • Focus on Five-One Free-Energy Expression
   • Focus on Zero-Zero Free-Energy Expression
   • Overview